// Copyright (C) Alias Systems, a division of Silicon Graphics Limited and/or
// its licensors ("Alias").  All rights reserved.  These coded instructions,
// statements, computer programs, and/or related material (collectively, the
// "Material") contain unpublished information proprietary to Alias, which is
// protected by Canadian and US federal copyright law and by international
// treaties.  This Material may not be disclosed to third parties, or be
// copied or duplicated, in whole or in part, without the prior written
// consent of Alias.  ALIAS HEREBY DISCLAIMS ALL WARRANTIES RELATING TO THE
// MATERIAL, INCLUDING, WITHOUT LIMITATION, ANY AND ALL EXPRESS OR IMPLIED
// WARRANTIES OF NON-INFRINGEMENT, MERCHANTABILITY AND/OR FITNESS FOR A
// PARTICULAR PURPOSE.  IN NO EVENT SHALL ALIAS BE LIABLE FOR ANY DAMAGES
// WHATSOEVER, WHETHER DIRECT, INDIRECT, SPECIAL, OR PUNITIVE, WHETHER IN AN
// ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, OR IN EQUITY,
// ARISING OUT OF OR RELATED TO THE ACCESS TO, USE OF, OR RELIANCE UPON THE
// MATERIAL.

global proc int TLmayaexportOpts ( string $parent,
									string $action,
									string $initialSettings,
									string $resultCallback )
{
        return 0;
}
 

global proc TLmayaexportOpts_ref( string $parent,
									string $action,
									string $initialSettings,
									string $resultCallback )
//
//	Description:
//		This script posts the GameExchange2 file translator options.
//		The optionsString is of the form:
//			varName1=value1;varName2=value2;...
//
//	Parameters:
//		$parent	- the elf parent layout for this options layout. It is
//					always a scrollLayout.
//		$action	- the action that is to be performed with this invokation
//					of this proc. Valid options are:
//						"query" - construct the options string and pass it
//									to the resultCallback.
//						"post"	- post all the elf controls.
//		$initialSettings - the current options string in effect at the
//						   time this script is invoked.
//		$resultCallback	-
//				This is the proc to be called with the result string. 
//				resultCallback ( string $optionsString )
//
//	Returns:
//		1 if successfull.
//		0 otherwise.
//
{
	string	$form;
	string  $tabs;
	int		$intVal;
	string	$strVal;
	float	$floatVal;
	int		$bResult;
	string	$currentOptions;
	string	$optionList[];
	string	$optionBreakDown[];
	int		$index;
	int		$counter;

	string	$texTypeString[] = { "als", "bmp", "png", "ppm", "sgi", "tif" };
	int		$defaultTexTypeIndex = 4;

	if ($action == "post") {
		setParent $parent;

		setUITemplate -pushTemplate DefaultTemplate;		

		formLayout -e -visible false optionsBoxForm;

		columnLayout -adj true;
			frameLayout
					-cll true 
					-cl true
					-bv true 
					-bs "etchedIn"
					-l "Domain Options" 
					tlsceneDomainFrame;

				columnLayout -adj true tlsceneDomainOptions;

					checkBoxGrp
							-l "Format data for domain:"
							-ncb 2
							-va2 true false
							-la2 "GL/DirectX" "SonyPSX"
							tlsceneDomainFlags;

					checkBoxGrp
							-l " "
							-ncb 2
							-va2 false false
							-la2 "N64" "Custom"
							tlsceneDomainFlags2;

				setParent ..; // columnLayout
			setParent ..; // frameLayout

			frameLayout 
					-cll true 
					-cl false 
					-bv true 
					-bs "etchedIn"
					-l "Animation Options" 
					tlsceneAnimateFrame;

				columnLayout -adj true tlsceneAnimateOptions;

					checkBoxGrp
							-l " "
							-ncb 1
							-v1 true
							-l1 "Enable Animation"
							-cc tlsceneSetAnim
							tlsceneAnimEnable;

					intSliderGrp -l "Start:" -f true -min 1 -max 1000 tlsceneAnimStart;
					intSliderGrp -e -v 1 tlsceneAnimStart;

					intSliderGrp -l "End:" -f true -min 1 -max 1000 tlsceneAnimEnd;
					intSliderGrp -e -v 1 tlsceneAnimEnd;

					intSliderGrp -l "Step:" -f true -min 1 -max 100 tlsceneAnimStep;
					intSliderGrp -e -v 1 tlsceneAnimStep;

					checkBoxGrp
							-l "Animate:"
							-ncb 2
							-va2 false true
							-cc tlsceneSetAnim
							-la2 "Vertices" "Transforms" tlsceneAnimFlags;

					checkBoxGrp
							-l " "
							-ncb 2
							-va2 true true
							-cc tlsceneSetAnim
							-la2 "Lights" "Camera" tlsceneAnimFlags2;

					checkBoxGrp
							-l "Keyframe using:"
							-ncb 2
							-va2 true false
							-cc tlsceneSetAnim
							-la2 "Anim Curves" "Sampling" tlsceneAnimKeyframe;

					intSliderGrp
							-l "Sample by" -field true
							-min 1 -max 50
							-v 1
							tlsceneAnimSampRate;

					floatSliderGrp
							-l "Tolerance"
							-field true
							-min 0.0 -max 5.0
							-v 0.5
							tlsceneAnimSampTolerance;

					radioButtonGrp
							-l "Animation displacement:"
							-nrb 2
							-la2 "Relative to Current Frame" "Absolute"
							-sl 1
							tlsceneAnimDisplacement;

				setParent ..; // columnLayout
			setParent ..; // frameLayout

			frameLayout 
					-cll true 
					-cl false 
					-bv true 
					-bs "etchedIn"
					-l "Export Options" 
					tlsceneExportFrame;

				columnLayout -adj true tlsceneExportOptions;

					radioButtonGrp
							-l "Hierarchy:"
							-nrb 3
							-la3 "World" "Flat" "Full" 
							-sl 1
							tlsceneHrcType;

					radioButtonGrp
							-l "Export:"
							-nrb 3
							-la3 "All" "Selected" "Active" 
							-sl 1
							tlsceneExportSel;

					radioButtonGrp
							-l "Tesselation:"
							-nrb 2
							-la2 "Tri" "Quad" 
							-sl 1
							tlsceneTesselation;

					checkBoxGrp
							-l "Export:"
							-ncb 2
							-va2 true true
							-la2 "Lights" "Camera"
							tlsceneExportFlags;

					checkBoxGrp
							-l ""
							-ncb 2
							-va2 true true
							-la2 "Textures" "Geometry"
							-cc1 tlsceneSetTextureExportOptions
							-cc2 tlsceneSetGeometryExportOptions
							tlsceneExportFlags2;

					checkBoxGrp
							-l ""
							-v1 true
							-l1 "Normals"
							-cc1 tlsceneSetNormalExportOptions
							tlsceneExportFlags3;

					checkBoxGrp
							-l "Export options:"
							-ncb 2
							-va2 false false
							-la2 "Reverse winding" "Flip normals"							
							tlsceneExportFlags4;

				setParent ..; // columnLayout
			setParent ..; // frameLayout

			frameLayout 
					-cll true 
					-cl true 
					-bv true 
					-bs "etchedIn"
					-l "Texture Options" 
					tlsceneTextureFrame;

				columnLayout -adj true tlsceneTextureOptions;

					checkBoxGrp
						-l " "
						-v1 true 
						-l1 "Use 2d and 3d texture placement"
						tlsceneTextureFlags;					

					checkBoxGrp
						-l " "
						-v1 true
						-l1 "Use convertSolidTx on file textures"
						tlsceneTextureFlags2;

					checkBoxGrp
						-l " "
						-v1 false
						-l1 "Use original file textures"
						tlsceneTextureFlags3;					

					separator -style "none";

					optionMenuGrp -l "Texture file type:" tlsceneTextureType;
						int $arraySize = size($texTypeString);
						for ( $counter = 0; $counter < $arraySize; $counter++ )
						{
							menuItem -label $texTypeString[$counter];
						}
					optionMenuGrp -e -sl ($defaultTexTypeIndex+1) tlsceneTextureType;

					intSliderGrp -l "X Tex Res" -field true 
										-max 10000 -fmx 4096 tlsceneXtexres;
					intSliderGrp -l "Y Tex Res" -field true 
										-max 10000 -fmx 4096 tlsceneYtexres;

					intSliderGrp -l "Max X Tex Res" -field true 
										-max 10000 -fmx 4096 tlsceneMaxXtexres;
					intSliderGrp -l "Max Y Tex Res" -field true 
										-max 10000 -fmx 4096 tlsceneMaxYtexres;
					intSliderGrp -e -v 256 tlsceneXtexres;
					intSliderGrp -e -v 256 tlsceneYtexres;
					intSliderGrp -e -v 4096 tlsceneMaxXtexres;
					intSliderGrp -e -v 4096 tlsceneMaxYtexres;					

					text -l "  Texture path:" -al "left";
					rowLayout -nc 2 -cw2 360 45; //-cl2 "both" "both";
						textField tlsceneTextPath;	
						button	-l "Browse" -rs true 
								-al "center" -c tlsceneBrowseForTextureSearchPath 
								tlsceneTexSPBrowser;
					setParent ..; // rowLayout


				setParent ..; // columnLayout				
			setParent ..; // frameLayout

			frameLayout 
					-cll true 
					-cl true
					-bv true 
					-bs "etchedIn"
					-l "Other Options" 
					tlsceneOtherFrame;

				columnLayout -adj true tlsceneOtherOptions;

		            optionMenuGrp -l "Float precision:" tlscenePrecision;
	                        menuItem -label ".x";
		                    menuItem -label ".xx";
			                menuItem -label ".xxx";
				            menuItem -label ".xxxx";
					        menuItem -label ".xxxxx";
						    menuItem -label ".xxxxxx";
					optionMenuGrp -e -sl 3 tlscenePrecision;

					checkBoxGrp
							-l "Format output:"
							-ncb 2
							-va2 true false
							-la2 "Tabs" "Comments"
							tlsceneOtherFlags;

					checkBoxGrp
							-l "Debug output:"
							-ncb 3
							-va3 false false false
							-la3 "Geometry" "Cameras" "Lights"
							tlsceneVerboseFlags;

					text -l "  Run script when done:" -al "left";

					rowLayout -nc 2 -cw2 360 45; //-cl2 "both" "both";
						textField tlsceneScript;
						button -l "Browse" -rs true -al "center" -c tlsceneBrowseForScript tlsceneScriptBrowser;
					setParent ..; // rowLayout


					text -l "  (Use forward slash (\"/\") for path delimiter)" -al "left";

					checkBoxGrp
							-l " "
							-ncb 1
							-v1 true
							-l1 "Append file name to script"
							tlsceneScriptAppend;


				setParent ..; // columnLayout
			setParent ..; // frameLayout

		setParent ..; // columnLayout

		setParent ..; // formLayout (optionsBoxForm)
		
		// Now set to current settings.

		$currentOptions = $initialSettings;
		if (size($currentOptions) > 0) 
		{
			tokenize($currentOptions, ";", $optionList);
			for ($index = 0; $index < size($optionList); $index++) 
			{
				tokenize($optionList[$index], "=", $optionBreakDown);

//
// Domain selection options
//
				 if ( $optionBreakDown[0] == "clDomain" )
				 {					 
					 $intVal = $optionBreakDown[1];
					 frameLayout -e -cl $intVal tlsceneDomainFrame;
				 }
				else
				 if ( $optionBreakDown[0] == "clAnimate" )
				 {
					 $intVal = $optionBreakDown[1];
					 frameLayout -e -cl $intVal tlsceneAnimateFrame;
				 }
				else
				 if ( $optionBreakDown[0] == "clExport" )
				 {
					 $intVal = $optionBreakDown[1];
					 frameLayout -e -cl $intVal tlsceneExportFrame;
				 }
				else
				 if ( $optionBreakDown[0] == "clTexture" )
				 {
					 $intVal = $optionBreakDown[1];
					 frameLayout -e -cl $intVal tlsceneTextureFrame;
				 }
				else
				 if ( $optionBreakDown[0] == "clOther" )
				 {
					 $intVal = $optionBreakDown[1];
					 frameLayout -e -cl $intVal tlsceneOtherFrame;
				 }
				else
				 if ( $optionBreakDown[0] == "useGL" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v1 $intVal tlsceneDomainFlags;
				 }
				else
				 if ( $optionBreakDown[0] == "usePSX" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v2 $intVal tlsceneDomainFlags;
				 }
				else
				 if ( $optionBreakDown[0] == "useN64" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v1 $intVal tlsceneDomainFlags2;
				 }
				else
				 if ( $optionBreakDown[0] == "useCustom" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v2 $intVal tlsceneDomainFlags2;
				 }


// Set Animation sliders
//
				else
				 if ( $optionBreakDown[0] == "enableAnim" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v1 $intVal tlsceneAnimEnable;
				 }
				else
				 if ( $optionBreakDown[0] == "animStart" ) 
				 {
					$intVal = $optionBreakDown[1];
					intSliderGrp -e -v $intVal tlsceneAnimStart;
				 }
				else
				 if ( $optionBreakDown[0] == "animEnd" ) 
				 {
					$intVal = $optionBreakDown[1];
					intSliderGrp -e -v $intVal tlsceneAnimEnd;
				 }
				else
				 if ( $optionBreakDown[0] == "animStep" ) 
				 {
					$intVal = $optionBreakDown[1];
					intSliderGrp -e -v $intVal tlsceneAnimStep;
				 }

// Post Animation flags
//
				else
				 if ( $optionBreakDown[0] == "animVertices" ) 
				 {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v1 $intVal tlsceneAnimFlags; 
				 }

				else
				 if ( $optionBreakDown[0] == "animTransforms" ) 
				 {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v2 $intVal tlsceneAnimFlags; 
				 }
				else
				 if ( $optionBreakDown[0] == "animLights" ) 
				 {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v1 $intVal tlsceneAnimFlags2; 
				 }
				else
				 if ( $optionBreakDown[0] == "animCamera" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v2 $intVal tlsceneAnimFlags2;
				 }
				else
				 if ( $optionBreakDown[0] == "keyCurves" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v1 $intVal tlsceneAnimKeyframe;
				 }
				else
				 if ( $optionBreakDown[0] == "keySample" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v2 $intVal tlsceneAnimKeyframe;
				 }
				else
				 if ( $optionBreakDown[0] == "sampRate" )
				 {
					 $intVal = $optionBreakDown[1];
					 intSliderGrp -e -v $intVal tlsceneAnimSampRate;
				 }
				else
				 if ( $optionBreakDown[0] == "sampTol" )
				 {
					 $floatVal = $optionBreakDown[1];
					 floatSliderGrp -e -v $floatVal tlsceneAnimSampTolerance;
				 }
				else
				 if ( $optionBreakDown[0] == "animDisplacement" )
				 {
					 $intVal = $optionBreakDown[1];
					 radioButtonGrp -e -sl $intVal tlsceneAnimDisplacement;
				 }

//
// Hierarchy and export selection
//				
				if ($optionBreakDown[0] == "hrcType") 
				{
					$intVal = $optionBreakDown[1];
                    radioButtonGrp -e -sl $intVal tlsceneHrcType;
				}
                else 
				 if ($optionBreakDown[0] == "exportSel") 
				 {
                    $intVal = $optionBreakDown[1];
					radioButtonGrp -e -sl $intVal tlsceneExportSel;
				 }  
				else 
				 if ($optionBreakDown[0] == "tesselation")
				 {
                    $intVal = $optionBreakDown[1] + 1;
					radioButtonGrp -e -sl $intVal tlsceneTesselation;
				}

 				else
				 if ( $optionBreakDown[0] == "exportLights" ) {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v1 $intVal tlsceneExportFlags; 
				 }
				else
				 if ( $optionBreakDown[0] == "exportCamera" ) {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v2 $intVal tlsceneExportFlags;
				 }
				else
				 if ( $optionBreakDown[0] == "exportTextures" ) {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v1 $intVal tlsceneExportFlags2;
				 }
				else
				 if ( $optionBreakDown[0] == "exportGeometry" ) {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v2 $intVal tlsceneExportFlags2;
				 }
				else
				 if ( $optionBreakDown[0] == "exportNormals" ) {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v1 $intVal tlsceneExportFlags3;
				 }
				else
				 if ( $optionBreakDown[0] == "reverse" ) {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v1 $intVal tlsceneExportFlags4;
				 }
				
				else
				 if ( $optionBreakDown[0] == "opposite" ) {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v2 $intVal tlsceneExportFlags4;
				 }

// Post texture options
//
                else
                 if ( $optionBreakDown[0] == "texsample" ) {
                    $intVal = $optionBreakDown[1];
					checkBoxGrp -e -v1 $intVal tlsceneTextureFlags; 
                 }  

                else
                 if ( $optionBreakDown[0] == "texevaluate" ) {
                    $intVal = $optionBreakDown[1];
                    checkBoxGrp -e -v1 $intVal tlsceneTextureFlags2;
                 }
				else
				 if ( $optionBreakDown[0] == "texOriginal" )
				 {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v1 $intVal tlsceneTextureFlags3;
				 }
                else
                 if ( $optionBreakDown[0] == "Xtexres" ) {
                    $intVal = $optionBreakDown[1];
                    intSliderGrp -e -v $intVal tlsceneXtexres;
                 }
                else
                 if ( $optionBreakDown[0] == "Ytexres" ) {
                    $intVal = $optionBreakDown[1];
                    intSliderGrp -e -v $intVal tlsceneYtexres;
                 }
                else
                 if ( $optionBreakDown[0] == "MaxXtexres" ) {
                    $intVal = $optionBreakDown[1];
                    intSliderGrp -e -v $intVal tlsceneMaxXtexres;
                 }
                else
                 if ( $optionBreakDown[0] == "MaxYtexres" ) {
                    $intVal = $optionBreakDown[1];
                    intSliderGrp -e -v $intVal tlsceneMaxYtexres;
                 }
				else
				 if ( $optionBreakDown[0] == "texType" )
				 {
					 // In case caller passes us one we don't know
					 optionMenuGrp -e -sl ($defaultTexTypeIndex+1) tlsceneTextureType;
					 $strVal = $optionBreakDown[1];
					 for ( $counter = 0; $counter < size($texTypeString); $counter++ )
					 {
						 if ( $strVal == $texTypeString[$counter] )
						 {
							 optionMenuGrp -e -sl ($counter+1) tlsceneTextureType;
							 break;
						 }
					 }
				 }
				else
				 if ( $optionBreakDown[0] == "textPath" )
				 {
					 textField -e -text $optionBreakDown[1] tlsceneTextPath;
				 }

//
// Other options...
				else
				 if ( $optionBreakDown[0] == "precision" )
				 {
					$intVal = $optionBreakDown[1];
					optionMenuGrp -e -sl $intVal tlscenePrecision;
				 }
				else
				 if ( $optionBreakDown[0] == "format" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v1 $intVal tlsceneOtherFlags;
				 }
				else
				 if ( $optionBreakDown[0] == "comments" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v2 $intVal tlsceneOtherFlags;
				 }
				else
				 if ( $optionBreakDown[0] == "verboseGeom" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v1 $intVal tlsceneVerboseFlags;
				 }
				else
				 if ( $optionBreakDown[0] == "verboseLgt" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v3 $intVal tlsceneVerboseFlags;
				 }
				else
				 if ( $optionBreakDown[0] == "verboseCam" )
				 {
					 $intVal = $optionBreakDown[1];
					 checkBoxGrp -e -v2 $intVal tlsceneVerboseFlags;
				 }
				else 
				 if ( $optionBreakDown[0] == "script" )
				 {
					 textField -e -tx $optionBreakDown[1] tlsceneScript;
				 }
				else
				 if ( $optionBreakDown[1] == "scriptAppend" )
				 {
					$intVal = $optionBreakDown[1];
					checkBoxGrp -e -v $intVal tlsceneScriptAppend;
				 }
			}
		}
		$bResult = 1;

		tlsceneSetAnim;
		tlsceneSetNormalExportOptions;
		tlsceneSetGeometryExportOptions;
		tlsceneSetTextureExportOptions;

		formLayout -e -visible true optionsBoxForm;

		setUITemplate -popTemplate;

	} else if ($action == "query") {

// Get collapse status
//
		$currentOptions = $currentOptions + "clDomain=" + `frameLayout -q -cl tlsceneDomainFrame` + ";";
		$currentOptions = $currentOptions + "clAnimate=" + `frameLayout -q -cl tlsceneAnimateFrame` + ";";
		$currentOptions = $currentOptions + "clExport=" + `frameLayout -q -cl tlsceneExportFrame` + ";";
		$currentOptions = $currentOptions + "clTexture=" + `frameLayout -q -cl tlsceneTextureFrame` + ";";
		$currentOptions = $currentOptions + "clOther=" + `frameLayout -q -cl tlsceneOtherFrame` + ";";
		
// Query animation range/step
//
		$currentOptions = $currentOptions + "enableAnim=" + `checkBoxGrp -q -v1 tlsceneAnimEnable` + ";";
		$currentOptions = $currentOptions + "animStart=" + `intSliderGrp -q -v tlsceneAnimStart` + ";";
		$currentOptions = $currentOptions + "animEnd=" + `intSliderGrp -q -v tlsceneAnimEnd` + ";";
		$currentOptions = $currentOptions + "animStep=" + `intSliderGrp -q -v tlsceneAnimStep` + ";";

// Query Anim options
//
		$currentOptions = $currentOptions + "animVertices=" + `checkBoxGrp -q -v1 tlsceneAnimFlags` + ";";
		$currentOptions = $currentOptions + "animTransforms=" + `checkBoxGrp -q -v2 tlsceneAnimFlags` + ";";
		$currentOptions = $currentOptions + "animLights=" + `checkBoxGrp -q -v1 tlsceneAnimFlags2` + ";";
		$currentOptions = $currentOptions + "animCamera=" + `checkBoxGrp -q -v2 tlsceneAnimFlags2` + ";";
		$currentOptions = $currentOptions + "keyCurves=" + `checkBoxGrp -q -v1 tlsceneAnimKeyframe` + ";";
		$currentOptions = $currentOptions + "keySample=" + `checkBoxGrp -q -v2 tlsceneAnimKeyframe` + ";";
		$currentOptions = $currentOptions + "sampRate=" + `intSliderGrp -q -v tlsceneAnimSampRate` + ";";
		$currentOptions = $currentOptions + "sampTol=" + `floatSliderGrp -q -v tlsceneAnimSampTolerance` + ";";
		$currentOptions = $currentOptions + "animDisplacement=" + `radioButtonGrp -q -sl tlsceneAnimDisplacement` + ";";

// Query domain selection
//
		$currentOptions = $currentOptions + "useGL=" + `checkBoxGrp -q -v1 tlsceneDomainFlags` + ";";
		$currentOptions = $currentOptions + "usePSX=" + `checkBoxGrp -q -v2 tlsceneDomainFlags` + ";";
		$currentOptions = $currentOptions + "useN64=" + `checkBoxGrp -q -v1 tlsceneDomainFlags2` + ";";
		$currentOptions = $currentOptions + "useCustom=" + `checkBoxGrp -q -v2 tlsceneDomainFlags2` + ";";

// Query hierarchy type and export options
//
		$currentOptions = $currentOptions + "hrcType=" + `radioButtonGrp -q -sl tlsceneHrcType` + ";";
		$currentOptions = $currentOptions + "exportSel=" + `radioButtonGrp -q -sl tlsceneExportSel` + ";";
		$currentOptions = $currentOptions + "tesselation=" + `radioButtonGrp -q -sl tlsceneTesselation` + ";";
		$currentOptions = $currentOptions + "exportLights=" + `checkBoxGrp -q -v1 tlsceneExportFlags` + ";";
		$currentOptions = $currentOptions + "exportCamera=" + `checkBoxGrp -q -v2 tlsceneExportFlags` + ";";
		$currentOptions = $currentOptions + "exportTextures=" + `checkBoxGrp -q -v1 tlsceneExportFlags2` + ";";
		$currentOptions = $currentOptions + "exportGeometry=" + `checkBoxGrp -q -v2 tlsceneExportFlags2` + ";";
		$currentOptions = $currentOptions + "exportNormals=" + `checkBoxGrp -q -v1 tlsceneExportFlags3` + ";";
		$currentOptions = $currentOptions + "reverse=" + `checkBoxGrp -q -v1 tlsceneExportFlags4` + ";";
		$currentOptions = $currentOptions + "opposite=" + `checkBoxGrp -q -v2 tlsceneExportFlags4` + ";";

// Query Texture options
//
		$currentOptions = $currentOptions + "texevaluate=" + `checkBoxGrp -q -v1 tlsceneTextureFlags` + ";";
		$currentOptions = $currentOptions + "texsample=" + `checkBoxGrp -q -v1 tlsceneTextureFlags2` + ";";
		$currentOptions = $currentOptions + "texOriginal=" + `checkBoxGrp -q -v1 tlsceneTextureFlags3` + ";";

        $currentOptions = $currentOptions + "Xtexres=" + `intSliderGrp -q -v tlsceneXtexres` + ";";
        $currentOptions = $currentOptions + "Ytexres=" + `intSliderGrp -q -v tlsceneYtexres` + ";";
        $currentOptions = $currentOptions + "MaxXtexres=" + `intSliderGrp -q -v tlsceneMaxXtexres` + ";";
        $currentOptions = $currentOptions + "MaxYtexres=" + `intSliderGrp -q -v tlsceneMaxYtexres` + ";";

		$currentOptions = $currentOptions + "texType=" + `optionMenuGrp -q -v tlsceneTextureType` + ";";
		$currentOptions = $currentOptions + "textPath=" + `textField -q -text tlsceneTextPath` + ";";

// Query other flags
//
        $currentOptions = $currentOptions + "precision=" + `optionMenuGrp -q -sl tlscenePrecision` + ";";
		$currentOptions = $currentOptions + "format=" + `checkBoxGrp -q -v1 tlsceneOtherFlags` + ";";
		$currentOptions = $currentOptions + "comments=" + `checkBoxGrp -q -v2 tlsceneOtherFlags` + ";";
		$currentOptions = $currentOptions + "verboseGeom=" + `checkBoxGrp -q -v1 tlsceneVerboseFlags` + ";";
		$currentOptions = $currentOptions + "verboseLgt=" + `checkBoxGrp -q -v2 tlsceneVerboseFlags` + ";";
		$currentOptions = $currentOptions + "verboseCam=" + `checkBoxGrp -q -v3 tlsceneVerboseFlags` + ";";

		$currentOptions = $currentOptions + "script=" + `textField -q -text tlsceneScript` + ";";
		$currentOptions = $currentOptions + "scriptAppend=" + `checkBoxGrp -q -v1 tlsceneScriptAppend` + ";";

		print( "Options: " + $currentOptions + "\n" );

		eval($resultCallback+" \""+$currentOptions+"\"");

		$bResult = 1;
	} else {
		$bResult = 0;
	}
	
	return $bResult;
}

global proc
tlsceneSetAnim()
{
	int $animEn = `checkBoxGrp -q -v1 tlsceneAnimEnable`;
	int $vertOn = `checkBoxGrp -q -v1 tlsceneAnimFlags`;
	int $transOn = `checkBoxGrp -q -v2 tlsceneAnimFlags`;
	int $lightsOn = `checkBoxGrp -q -v1 tlsceneAnimFlags2`;
	int $cameraOn = `checkBoxGrp -q -v2 tlsceneAnimFlags2`;
	int $sampOn = `checkBoxGrp -q -v2 tlsceneAnimKeyframe`;

	int $enableDisplacement;
	int $enableKeyframe;
	int $enableSliders;

	if ( !$animEn )
	{
		$enableDisplacement = false;
		$enableKeyframe = false;
		$enableSliders = false;
	}
	else {
		if ( $vertOn )
			$enableDisplacement = true;
		else
			$enableDisplacement = false;
		if ( $vertOn || $transOn || $lightsOn || $cameraOn )
			$enableKeyframe = true;
		else
			$enableKeyframe = false;
		if ( $sampOn )
			$enableSliders = true;
		else
			$enableSliders = false;
	}

	checkBoxGrp -e -en1 $enableKeyframe tlsceneAnimKeyframe;
	checkBoxGrp -e -en2 $enableKeyframe tlsceneAnimKeyframe;
	intSliderGrp -e -en $enableSliders tlsceneAnimSampRate;
	floatSliderGrp -e -en $enableSliders tlsceneAnimSampTolerance;
	radioButtonGrp -e -en $enableDisplacement tlsceneAnimDisplacement;

	tlsceneSetAnimSliders( $animEn );
	tlsceneSetAnimFlags( $animEn );	
}

global proc
tlsceneSetAnimSliders( int $enable )
{
	intSliderGrp -e -en $enable tlsceneAnimStart;
	intSliderGrp -e -en $enable tlsceneAnimEnd;
	intSliderGrp -e -en $enable tlsceneAnimStep;

	int $enKeyAnimCurves = `checkBoxGrp -q -en1 tlsceneAnimKeyframe`;
	int $keyAnimCurves = `checkBoxGrp -q -v1 tlsceneAnimKeyframe`;

	if ( $enKeyAnimCurves && $keyAnimCurves )
	{
		intSliderGrp -e -v 1 tlsceneAnimStep;
		intSliderGrp -e -en false tlsceneAnimStep;
	}
}

global proc
tlsceneSetAnimFlags( int $enable )
{
	checkBoxGrp -e -en1 $enable tlsceneAnimFlags;
	checkBoxGrp -e -en2 $enable tlsceneAnimFlags;
	checkBoxGrp -e -en1 $enable tlsceneAnimFlags2;
	checkBoxGrp -e -en2 $enable tlsceneAnimFlags2;
}

global proc
tlsceneSetNormalExportOptions()
{
	int $selected = `checkBoxGrp -q -v1 tlsceneExportFlags3`;
	int $enabled = `checkBoxGrp -q -en1 tlsceneExportFlags3`;

	if ( $selected && $enabled )
	{
		checkBoxGrp -e -en2 true tlsceneExportFlags4;
	} else
	{
		checkBoxGrp -e -en2 false tlsceneExportFlags4;
	}
}

global proc
tlsceneSetGeometryExportOptions()
{
	int $enable = `checkBoxGrp -q -v2 tlsceneExportFlags2`;
	// Disable normals:
	checkBoxGrp -e -en1 $enable tlsceneExportFlags3;
	// Disable reverse winding
	checkBoxGrp -e -en1 $enable tlsceneExportFlags4;

	// tell Normal options to do what it will with opposites
	tlsceneSetNormalExportOptions();
}

global proc
tlsceneSetTextureExportOptions()
{
	int $enable = `checkBoxGrp -q -v1 tlsceneExportFlags2`;

	checkBoxGrp -e -en $enable tlsceneTextureFlags;
	checkBoxGrp -e -en $enable tlsceneTextureFlags2;
	checkBoxGrp -e -en $enable tlsceneTextureFlags3;

	optionMenuGrp -e -en $enable tlsceneTextureType;
	intSliderGrp -e -en $enable tlsceneXtexres;
	intSliderGrp -e -en $enable tlsceneYtexres;
	intSliderGrp -e -en $enable tlsceneMaxXtexres;
	intSliderGrp -e -en $enable tlsceneMaxYtexres;

	textField -e -en $enable tlsceneTextPath;
}

global proc 
tlsceneSetTextureSearchPath(string $path, string $type)
{
	string $currSearchPath = `textField -q -text tlsceneTextPath`;
	if ( "" == $currSearchPath )
		$currSearchPath = $path;
	else
		$currSearchPath = $currSearchPath + "|" + $path;
	textField -e -text $currSearchPath tlsceneTextPath;
}

global proc
tlsceneBrowseForTextureSearchPath()
{
	fileBrowser "tlsceneSetTextureSearchPath" "Select Texture Path" "" 4;
}

global proc
tlsceneBrowseForScript()
{
	string $file = `fileDialog`;
	textField -e -text $file tlsceneScript;
}